Como instalar e configurar um Medidor de Energia com PZEM-004T

[RodolfoVieira (Rodolfo)]

Se queres ter um medidor de energia no teu Home Assistant…existe já alguns equipamentos no mercado que podes instalar e configurar, AQUI já te tinha demonstrado como poderias usar um medidor de energia usando um SDM120, mas agora vou te demonstrar como podes “construir” outro mas a partir de um Pzem 004-t.

Bom, então o vais precisar?

Lista de material:

1x - Pzem 004-t
1x - NodeMcu v3 ou sonoff basic
1x - Hlk-pm 01 caso optes por sonoff basic o hlk não é necessário
vários jumpers ou fios

Isto fica-te mais ou menos em 10 eur coisa menos coisa.

Tens aqui o esquema de ligação:

O esquema está mal não deves usar os pinos D1 e D2, mas sim o Tx e RX.

Com o pzem podes medir até 100 Amperes, ou seja se quiseres medir o consumo total de tua casa podes por exemplo colocar o fio da fase que vai do teu dijuntor da EDP até ao teu dijuntor geral.
Ou se quiseres medir um dijuntor especifico também o podes fazer…é como queiras.

Em baixo deixo-te o código que deves flashar no teu nodemcu com o arduino IDE

Código:

/**
  Copyright 2017 Bruno Horta
  Permission is hereby granted, free of charge, to any person obtaining a copy of this software and associated documentation files (the "Software"), to deal in the Software without restriction, including without limitation the rights to use, copy, modify, merge, publish, distribute, sublicense, and/or sell copies of the Software, and to permit persons to whom the Software is furnished to do so, subject to the following conditions:
  The above copyright notice and this permission notice shall be included in all copies or substantial portions of the Software.
  THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
*/
//MQTT - como instalar -> https://www.youtube.com/watch?v=GMMH6qT8_f4
#include <PubSubClient.h>
//ESP - como instalar -> https://www.youtube.com/watch?v=4d8joORYTIA&t=1s
#include <ESP8266WiFi.h>
//Wi-Fi Manager  como instalar -> https://www.youtube.com/watch?v=wWO9n5DnuLA
#include <DNSServer.h>
#include <ESP8266WebServer.h>
#include <WiFiManager.h>

//OTA -> já está incluida no IDE do Arudino
#include <WiFiUdp.h>
#include <ArduinoOTA.h>
#include <SoftwareSerial.h> //-> https://github.com/plerup/espsoftwareserial
#include <PZEM004T.h> // -> https://github.com/olehs/PZEM004T

PZEM004T pzem(5,4);  // (RX,TX) connect to TX,RX of PZEM
IPAddress ip(192,168,1,1);

// Configuração do acesso ao Broker MQTT
#define MQTT_AUTH true
#define MQTT_USERNAME "username"
#define MQTT_PASSWORD "password"

//Constantes
const String HOSTNAME = "contadorpzem";             //NOME DO DEVICE, este nome tambem é utilizado apra criar o Access Point para configuração
const char *OTA_PASSWORD = "otapower";                // Password para atualizar o Firmware Over the Air
const char *MQTT_LOG = "system/log";                  // Topico onde o Device Publica informações relacionadas com o sistema
const char *MQTT_SYSTEM_CONTROL_TOPIC = "system/set"; // Topico onde o Device subscreve para aceitar instruções de sistema

const char *MQTT_TEST_TOPIC = "superTopic"; //Topico de exemplo onde o Device subscreve (por exemplo controlar uma lâmpada)
//MQTT BROKERS GRATUITOS PARA TESTES https://github.com/mqtt/mqtt.github.io/wiki/public_brokers
const char *MQTT_SERVER = "hassio.lan"; //IP ou DNS do Broker MQTT

WiFiClient wclient;
PubSubClient client(MQTT_SERVER, 1883, wclient);

//FLAGS de Controlo
bool OTA = false; //O Serviço OTA é muito pesado para estar sempre ativo por isso é ligado via MQTT e fica disponivel até ser desligado ou até o device ser reiniciado
bool OTABegin = false;



void setup() {
  Serial.begin(115200);
  WiFiManager wifiManager;

  pzem.setAddress(ip);

  //wifiManager.resetSettings(); //Limpa a configuração anterior do Wi-Fi SSID e Password, procedimento, 1º descomentar a linha, 2º Fazer Upload do código para o ESP e deixar o ESP arrancar, 3º Voltar a comentar a linha e enviar novamente o código para o ESP
  /*define o tempo limite até o portal de configuração ficar novamente inátivo,
    útil para quando alteramos a password do AP*/
  wifiManager.setTimeout(180);
  wifiManager.autoConnect(HOSTNAME.c_str());
  client.setCallback(callback); //Registo da função que vai responder ás mensagens vindos do MQTT

  
}

//Chamada de recepção de mensagem
void callback(char *topic, byte *payload, unsigned int length) {
  String payloadStr = "";
  for (int i = 0; i < length; i++) {
    payloadStr += (char)payload[i];
  }
  String topicStr = String(topic);
  if (topicStr.equals(MQTT_SYSTEM_CONTROL_TOPIC)) {
    if (payloadStr.equals("OTA_ON_" + String(HOSTNAME))) {
      Serial.println("OTA ON");
      OTA = true;
      OTABegin = true;
    } else if (payloadStr.equals("OTA_OFF_" + String(HOSTNAME))) {
      Serial.println("OTA OFF");
      OTA = false;
      OTABegin = false;
    } else if (payloadStr.equals("REBOOT_" + String(HOSTNAME))) {
      Serial.println("REBOOT");
      ESP.restart();
    }
  } else if (topicStr.equals(MQTT_TEST_TOPIC)) {
    //TOPICO DE TESTE
    Serial.println(payloadStr);
  }
}

bool checkMqttConnection() {
  if (!client.connected()) {
    if (MQTT_AUTH ? client.connect(HOSTNAME.c_str(), MQTT_USERNAME, MQTT_PASSWORD) : client.connect(HOSTNAME.c_str())) {
      Serial.println("CONNECTED TO MQTT BROKER " + String(MQTT_SERVER));
      client.publish(MQTT_LOG, String("CONNECTED_" + HOSTNAME).c_str());
      //SUBSCRIÇÃO DE TOPICOS
      client.subscribe(MQTT_SYSTEM_CONTROL_TOPIC);
      client.subscribe(MQTT_TEST_TOPIC);
    }
  }
  return client.connected();
}

void loop() {
  if (WiFi.status() == WL_CONNECTED) {
    if (checkMqttConnection()) {
      client.loop();
      if (OTA) {
        if (OTABegin) {
          setupOTA();
          OTABegin = false;
        }
        ArduinoOTA.handle();
      }

       float v = pzem.voltage(ip);
  if (v < 0.0) v = 0.0;
  Serial.print(v);Serial.print("V; ");

  float i = pzem.current(ip);
  if(i >= 0.0){ Serial.print(i);Serial.print("A; "); }
  
  float p = pzem.power(ip);
  if(p >= 0.0){ Serial.print(p);Serial.print("W; "); }
  
  float e = pzem.energy(ip);
  if(e >= 0.0){ Serial.print(e);Serial.print("Wh; "); }

    String tensao = String(v);
    String corrente = String(i);
    String potencia = String(p);
    String consumo = String(e);

    String payload = "{";
    payload += "\"tensao\":"; payload += tensao; payload += ",";
    payload += "\"corrente\":"; payload += corrente; payload += ",";
    payload += "\"potencia\":"; payload += potencia; payload += ",";
    payload += "\"consumo\":"; payload += consumo; 
    payload += "}";
    
    char attributes[100];
    payload.toCharArray( attributes, 100 );
    client.publish( "system/contagem", attributes );
    Serial.println( attributes );
   
    }
    
  }
}

void setupOTA() {
  if (WiFi.status() == WL_CONNECTED && checkMqttConnection()) {
    client.publish(MQTT_LOG, "OTA SETUP");
    ArduinoOTA.setHostname(HOSTNAME.c_str());
    ArduinoOTA.setPassword(OTA_PASSWORD);

    ArduinoOTA.onStart([]() {
      client.publish(MQTT_LOG, "START");
    });
    ArduinoOTA.onEnd([]() {
      client.publish(MQTT_LOG, "END");
    });
    ArduinoOTA.onProgress([](unsigned int progress, unsigned int total) {
      String p = "Progress: " + String((progress / (total / 100)));
      client.publish(MQTT_LOG, p.c_str());
    });
    ArduinoOTA.onError([](ota_error_t error) {
      if (error == OTA_AUTH_ERROR)
        client.publish(MQTT_LOG, "Auth Failed");
      else if (error == OTA_BEGIN_ERROR)
        client.publish(MQTT_LOG, "Begin Failed");
      else if (error == OTA_CONNECT_ERROR)
        client.publish(MQTT_LOG, "Connect Failed");
      else if (error == OTA_RECEIVE_ERROR)
        client.publish(MQTT_LOG, "Receive Failed");
      else if (error == OTA_END_ERROR)
        client.publish(MQTT_LOG, "End Failed");
    });
    ArduinoOTA.begin();
  }
}

Créditos para o código Bruno Horta

Por fim deixo-te o código que deves colocar no teu configuration.yaml

  sensors:
    - platform: mqtt
      state_topic: 'system/contagem'
      name: 'Tensao'
      unit_of_measurement: 'V'
      value_template: '{{ value_json.tensao }}'
    - platform: mqtt
      state_topic: 'system/contagem'
      name: 'Corrente'
      unit_of_measurement: 'A'
      value_template: '{{ value_json.corrente }}'
    - platform: mqtt
      state_topic: 'system/contagem'
      name: 'Potencia'
      unit_of_measurement: 'W'
      value_template: '{{ value_json.potencia }}'
    - platform: mqtt
      state_topic: 'system/contagem'
      name: 'Consumo'
      unit_of_measurement: 'Wh'
      value_template: '{{ value_json.consumo }}'

Dentro do teu groups.yaml colocas isto:

_consumo_:
  view: yes
  name: Consumos
  entities:
    - group.consumo
    
consumo:
  entities:
    - sensor.tensao
    - sensor.potencia
    - sensor.corrente
    - sensor.consumo

Caso queiras optar por simplificar a coisa e usares o pzem com um sonoff basic este é o esquema:

Deves flashar o sonoff Basic com o firmware tasmota, podes faze-lo usando este Tutorial quando já tiveres o sonoff flashado e configurado na Consola deves escrever o comando: SerialLog 0

Na configuração do Modulo escolhes Generic e colocas tambem toda a informação como ves na imagem:

É tambem importar definires o tele period para 15, podes faze-lo no botão que diz:

E colocas a 15

Por fim se tudo correu bem, deverás ter algo como isto a aparecer:

A configuração para colocares no HA será:

homeassistant:

sensor:

  - platform: mqtt
    name: "Watts"
    state_topic: "tele/pzem/SENSOR"
    value_template: "{{ value_json.ENERGY.Power }}"
    unit_of_measurement: "W"
    icon: mdi:power-plug

  - platform: mqtt
    name: "Voltagem"
    state_topic: "tele/pzem/SENSOR"
    value_template: "{{ value_json.ENERGY.Voltage }}"
    unit_of_measurement: "V"
    icon: mdi:flash

  - platform: mqtt
    name: "Corrente"
    state_topic: "tele/pzem/SENSOR"
    value_template: "{{ value_json.ENERGY.Current }}"
    unit_of_measurement: "A"
    icon: mdi:power-socket


  - platform: mqtt
    name: "Consumo Diário"
    state_topic: "tele/pzem/SENSOR"
    value_template: "{{ value_json.ENERGY.Today }}"
    unit_of_measurement: "kWh"
    icon: mdi:power-socket-eu

  - platform: mqtt
    name: "Consumo dia Anterior"
    state_topic: "tele/pzem/SENSOR"
    value_template: "{{ value_json.ENERGY.Yesterday }}"
    unit_of_measurement: "kWh"
    icon: mdi:power-socket-eu

  - platform: mqtt
    name: "Consumo Total"
    state_topic: "tele/pzem/SENSOR"
    value_template: "{{ value_json.ENERGY.Total }}"
    unit_of_measurement: "kWh"
    icon: mdi:power-socket-eu

#  - platform: mqtt
#    name: "Factor Potência"
#    state_topic: "tele/pzem/SENSOR"
#    value_template: "{{ value_json.ENERGY.Factor }}"
#    icon: mdi:percent
     
      
group:
  
  energia:
    view: yes
    icon: mdi:power-socket
    entities:
      - group.energiagroup

  energiagroup:
    control: hidden
    name: Consumo Energético
    entities:
      - sensor.watts
      - sensor.voltagem
      - sensor.corrente
      - sensor.consumo_diario
      - sensor.consumo_dia_anterior
      - sensor.consumo_total
      #- sensor.power_factor

Em alternativa caso uses o pzem vendido pelo @brunohorta e queiras instalar o firmware tasmota podes ver neste Tópico como configurar.

Como instalar e configurar um Medidor de Energia PZEM-004T

Para quem quiser configurar um Medidor de Energia PZEM-004T usando Tasmota aqui vai como configurar No meu caso to a usar o PZEM-BH produzido pelo amigo Bruno Horta. Queria desde já tambem agradecer ao nosso amigo Rodolfo Vieira pela ajuda que deu. Em primeiro lugar vamos flashar o nosso PZEM com o tasmota de seguida vamos configurar o modulo em modo generico e vamos configurar os respetivos GPIOS de acordo com os modulos PZEM que usarem(no meu caso o PZEM do Bruno Horta) [1] [3] de s…

Caso tenhas já uses o pzem e uses outras configurações mostra nos como tens feito.

[system]

Para comentar este tópico, por favor utilizem o tópico abaixo.

Como instalar e configurar um Medidor de Energia PZEM-004T

https://forum.cpha.pt/t/como-instalar-e-configurar-um-medidor-de-energia-pzem-004t/540